讀懂工作台的 CQL

範例條文

整頁都用這一條。工作台把它拆成四個原子條件和兩個群組：

本品限內科專科醫師處方，病人需為成人（年滿十八歲），且 eGFR ≥ 30 mL/min/1.73m²；未達標準者，須經腎臟科會診同意後使用。

完整的 CQL

這是 renderCql 為這條條文產生的完整檔案。接下來四節由上往下，一段一段說明。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

library Clause_Sample version '1.0.0'

using FHIR version '4.0.1'

/* Evidence adapters supply true, false, or null for each reviewed criterion. */
parameter "C1" Boolean default null
parameter "C2" Boolean default null
parameter "C3" Boolean default null
parameter "C4" Boolean default null

context Patient

define "Criterion C1":
  "C1"

define "Criterion C2":
  "C2"

define "Criterion C3":
  "C3"

define "Criterion C4":
  "C4"

define "Group G1":
  "Criterion C1"
  and "Criterion C2"
  and "Group G2"

define "Group G2":
  "Criterion C3"
  or "Criterion C4"

define "Eligibility":
  "Group G1"

define "Eligibility Status":
  if "Eligibility" is true then 'eligible'
  else if "Eligibility" is false then 'ineligible'
  else 'insufficient-data'

標頭：library、using、context

第 1、3、11 行說明這份檔案是什麼、用什麼資料模型、替誰計算。

library Clause_Sample version '1.0.0'

這份邏輯的名稱和版本號，匯出後靠它辨認是哪一份。

using FHIR version '4.0.1'

宣告資料模型是 FHIR R4。工作台的邏輯其實不直接讀 FHIR 資料，原因在下一節。

context Patient

這行之後的每個 define，都是針對一位病人計算。

參數：每個條件一個輸入

每個原子條件對應一個 parameter，型別是 Boolean。CQL 本身不查病歷：證據轉接器（evidence adapter）先查好，再把答案當成參數傳進來。

parameter "C3" Boolean default null

每個參數只會是下面三種值之一，以 C3（eGFR ≥ 30）為例：

default null 的意思是：沒有人提供值的時候，就當作「不知道」，而不是「不符合」。

define：替一段運算取名字

define 後面接名稱和冒號，下一行開始是它的內容。工作台產生三層 define：

define "Criterion C3":
  "C3"

define "Group G2":
  "Criterion C3"
  or "Criterion C4"

define "Eligibility":
  "Group G1"

• Criterion C3 直接取參數 C3 的值。
• Group G2 就是審核畫面上的 G2：C3 或 C4 任一符合。
• Eligibility 指向最外層的 G1，也就是整條條文的判斷。

小提醒：雙引號包的是名稱，例如 "Group G2"；單引號包的是文字，例如 'eligible'。

三值邏輯：遇到 null 怎麼算

參數可能是 null，所以 and、or、not 都要處理「不知道」。規則只有一句：答案已經確定，就不管 null；還不確定，結果就是 null。

例如 false and null 是 false：只要有一個條件不符合，「全部符合」就不可能成立，另一個是什麼都一樣。true or null 是 true，道理相同。

結果：為什麼寫 is true

最後一個 define 把三值結果轉成三種狀態：

define "Eligibility Status":
  if "Eligibility" is true then 'eligible'
  else if "Eligibility" is false then 'ineligible'
  else 'insufficient-data'

is true 只在值是 true 時成立；遇到 null 會得到 false，而不是 null。所以三個分支剛好對應三種結果：符合、不符合、資料不足。

define "Eligibility Status":
  if "Eligibility" then 'eligible'
  else 'ineligible'

四種情境走一遍

把四組參數帶進去，由內往外算：先算 G2，再算 G1。

第三列的 C3 是 null，但 C4 是 true，null or true 已經確定是 true，所以仍然符合。第四列的 C3、C4 都是 null，G2 無法確定，整條就是資料不足，要等補上 eGFR 或會診紀錄再算。

自己試試看

把每個條件切成符合、不符合或查不到，看 G2、G1 和最後的結果怎麼跟著變。可以先套用上表的情境，再改其中一格。

常見問題

下一步